13. Padrões, seções e forma

▶ Abrir no Aratu para ouvir e mudar os exemplos

O material é preparado antes e ganha um nome:

pattern groove {
  hh = cc cc co cc
  bd = b - b -
  sd = - s - s
}

pattern fill {
  hh = cc cc cc cc
  bd = bb -b bb -b
  sd = ss ss SS SS
}

play groove
at bar 4: play fill
at bar 5: play groove

Forma

Seções são partes da peça com nome, e uma linha de forma as ordena:

section intro  { baixo = | lá2 _ _ _ | mi2 _ _ _ | }
section verso  {
  baixo = | lá2 _ mi2 _ | fá2 _ dó3 _ |
  drums { hh = cc cc co cc; bd = b - b - }
}
section refrao {
  violão { chords = | Am | F | C | G |; strum = D du -u du }
}
section final  { baixo = | lá2 _ _ _ | }

form: intro verso x2 refrao verso refrao x2 final

Uma seção guarda partes e linhas como a peça inteira, e dura o tanto da sua linha mais longa. A forma toca as seções em ordem (x2 toca uma duas vezes) e então recomeça. Um bloco pode ficar numa linha só, com ; entre as linhas.

Variar um loop

pattern groove { hh = cc cc co cc; bd = b - b -; sd = - s - s }
pattern fill   { hh = cc cc cc cc; sd = ss ss SS SS }
pattern crash  { cr = x - - - }

play groove x3, fill
every 8 bars, first: add crash

play escolhe o padrão que soa; play groove x3, fill toca uma frase de padrões em sequência e a repete. every 4 bars: play fill toca a virada no quarto compasso de cada quatro, no lugar do groove; add toca um padrão por cima do que está soando.

Um play vale até outro: at bar 8: play fill toca a virada do compasso 8 em diante. once (uma vez) toca o padrão uma vez e volta:

at bar 8: play fill once     // a virada no compasso 8, o groove de volta no 9
now: play fill once          // uma virada já, depois o groove onde estaria
now: add crash once          // um prato por cima, uma vez

O padrão que estava tocando continua contando os compassos enquanto isso, então play groove x3, fill não perde o lugar na frase. Com every, o padrão já toca uma vez a cada volta.